以下是大智慧同舟共济六个基本指标副图源码（无源码的请下载附件导入）

由于本人年老体衰发此告别帖希望给大家留个念想，本公式涵盖【KDJ】【CCI】【MACD】【DMA】【RSI】【W&R】六大指标，我认为是【原创】请笑纳
每个指标包涵：-----
第一：原来的基本公式------以虚线出现在图上.
第二：变相的原指标适用于做波段及时发现高低点有利于找出买卖点.-------用粗线表示
第三：配合对应大盘的相应指标及时发现大盘的走向和个股的关联，-------以点线表示，
第四：个公式之间可利用调整参数开关，对比，查阅.背景也跟指标变化以示区别，
第五：你每次就显示一个指标否则图面太烂，太花，一带六编时复杂些 你会用，各用各的，用起来并不复杂。
第六：既然是告别恕我不再解答，自己梦自己原吧，好心人可替代我解答；也可改为【通达信】的。只要记得我就行，
 

{同舟共济}
input:N(1,0,1),M(1,0,1),P(1,0,1),G(1,0,1),S(1,0,1),W(1,0,1);
IF N=1 THEN BEGIN
DRAWGBKlast(DATE>900101,strip(RGB(0,60,0),RGB(0,0,0),0));
DRAWTEXTABS(50,8,'【KDJ--9,18】'),Color0077FF,LINETHICK4;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,3,1),COLORFF9000,DOTLINE;
D:SMA(K,3,1),COLOR00FF00,DOTLINE;
J:(3*K-2*D),COLOR0000FF,DOTLINE;
J18:EMA(EMA("KDJ.J"(18,3,3),5),8),COLORFF9900,LINETHICK1;
PARTLINE(J18,J18>REF(J18,1),rgb(255,0,0)),LINETHICK3,LAYER0;

{大盘KDJ}
DPRSV:=(INDEXC-LLV(INDEXL,18))/(HHV(INDEXH,18)-LLV(INDEXL,45))*100;
DPK:=SMA(DPRSV,3,1);
DPD:=SMA(DPK,3,1);
DPJ:EMA((3*DPK-2*DPD),5),COLOR00FFFF;
PARTLINE(DPJ,(DPJ>REF(DPJ,1))-1,rgb(0,255,0),1,rgb(255,0,0) ),POINTDOT,LINETHICK6,LAYER1;
END;

IF M=1 THEN BEGIN
DRAWGBKlast(DATE>900101,strip(RGB(0,0,150),RGB(0,0,0),0));
DRAWTEXTABS(200,8,'【CCI--14,18】'),Color00FFFF,LINETHICK4;
TYP := (HIGH + LOW + CLOSE)/3;
CCI:(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14))/2,DOTLINE;
CCIJ:EMA(EMA(EMA((TYP-WMA(TYP,18))/(0.015*AVEDEV(TYP,18)),4),6),8),colorFF9900;
Xl:=slope(CCIJ,3)>0;
PARTLINE(CCIJ,Xl,rgb(255,0,0)),LINETHICK3,LAYER2;

{大盘CCI}
TYPD := (INDEXH + INDEXL + INDEXC)/3;
大盘CCI:EMA(EMA(EMA((TYPD-WMA(TYPD,18))/(0.015*AVEDEV(TYPD,18)),4),6),8),color00FFFF,DOTLINE;
大盘Xl:=slope(大盘CCI,3)>0;
PARTLINE(大盘CCI,(大盘Xl)-1,rgb(0,200,0),1,rgb(200,0,0) ),POINTDOT,LINETHICK5;
END;
IF P=1 THEN BEGIN
DRAWGBKlast(DATE>900101,strip(RGB(80,80,0),RGB(0,0,0),0));
DRAWTEXTABS(350,8,'【MACD--11,21,5】'),Color0000FF,LINETHICK4;
DIFF :EMA( EMA(CLOSE,11) - EMA(CLOSE,21),3),COLOR0000FF,LINETHICK2;
DEA : EMA(DIFF,5),COLOR00FF00,LINETHICK2;
MACD : 2*(DIFF-DEA),LINETHICK0;
STICKLINE(MACD>0,MACD,0,2,0),Color0000FF;
STICKLINE(MACD<0,MACD,0,2,0),Color00FF00;
{大盘MACD}
DIFF大盘 :EMA( EMA(INDEXC,11) - EMA(INDEXC,21),3)/100,Color00FFFF,DOTLINE;
DEA大盘 : EMA(DIFF大盘,5),ColorFF9900,DOTLINE;
MACD大盘 := 2*(DIFF大盘-DEA大盘);
STICKLINE(MACD大盘>0,-0.4+MACD大盘,-0.4,1,0),Color00FFFF;
STICKLINE(MACD大盘<0,-0.4+MACD大盘,-0.4,1,0),ColorFF9900;
END;
IF G=1 THEN BEGIN
DRAWGBKlast(c>0,strip(RGB(0,40,0),RGB(0,0,40),0));;
DRAWTEXTABS(500,8,'【DMA--10,50,10】'),ColorFF00FF,LINETHICK4;
DDD:EMA((MA(CLOSE,10)-MA(CLOSE,50)),5);
AMA:MA(DDD,10),COLOR00FFFF;
FILLRGN(DDD,AMA,DDD>AMA,RGB(120,0,80)),LAYER7;
FILLRGN(DDD,AMA,DDD<AMA,RGB(0,80,0)),LAYER7;
{大盘DMA}
大盘DDD:EMA((MA(INDEXC,10)-MA(INDEXC,50)),5)/INDEXC*CLOSE*2,Color0077FF,DOTLINE;
大盘AMA:MA(大盘DDD,10),COLORFF9900,DOTLINE;
END;
IF S=1 THEN BEGIN
DRAWGBKlast(c>0,strip(RGB(0,40,0),RGB(0,0,100),0));;
DRAWTEXTABS(650,8,'【RSI--14】'),Color00FF00,LINETHICK4;
LC := REF(CLOSE,1);
RSI:SMA(MAX(CLOSE-LC,0),14,1)/SMA(ABS(CLOSE-LC),14,1)*100,COLORFF9900;
MRSI:EMA(EMA(EMA(RSI,3),6),9),COLOR00FF00;
PARTLINE(MRSI,MRSI>REF(MRSI,1),rgb(255,0,0)),LINETHICK3,LAYER0;
DRAWTEXT(CROSS(ref(MRSI,1),MRSI) ,MRSI*1.06,'▼'),COLOR0598FF,ALIGN1,LINETHICK1;
{大盘RSI}
DPLC := REF(INDEXC,1);
DPRSI:=SMA(MAX(INDEXC-DPLC,0),14,1)/SMA(ABS(INDEXC-DPLC),14,1)*100;
DPMRSI:EMA(EMA(EMA(DPRSI,3),6),9),COLORFF9900;
PARTLINE(DPMRSI,(DPMRSI>REF(DPMRSI,1))-1,rgb(0,255,0),1,rgb(255,0,0) ),POINTDOT,LINETHICK4,LAYER1;
END;

IF W=1 THEN BEGIN
DRAWGBKlast(DATE>900101,strip(RGB(0,80,0),RGB(0,0,0),0));
DRAWTEXTABS(800,8,'【W&R--14反向用】'),Color00FFFF,LINETHICK4;
WR1:-100*(HHV(HIGH,14)-CLOSE)/(HHV(HIGH,14)-LLV(LOW,14)),Color00FF00;
WR2:-100*(HHV(HIGH,20)-CLOSE)/(HHV(HIGH,20)-LLV(LOW,20)),Color00FFff,DOTLINE;
WRM:EMA(EMA(EMA(WR1,3),6),9),Color00FFFF,LINETHICK1;
PARTLINE(WRM,WRM>REF(WRM,1),rgb(255,0,0)),LINETHICK4,LAYER0;
DRAWTEXT(CROSS(REF(WRM,1),WRM) ,WRM*0.85,'▼'),COLOR0598FF,ALIGN1,LINETHICK1;
DPWR1:=-100*(HHV(INDEXH,14)-INDEXC)/(HHV(INDEXH,14)-LLV(INDEXL,14));
DPMWR1:EMA(EMA(EMA(DPWR1,3),6),9),COLORFF9900;
PARTLINE(DPMWR1,(DPMWR1>REF(DPMWR1,1))-1,rgb(0,255,0),1,rgb(255,0,0) ),POINTDOT,LINETHICK4,LAYER1;
END;