以下是阿旺大智慧通用版数据和公式使用讲解（无源码的请下载附件导入）

说句实在话 我并不喜欢独立发公式 因为我水平是有限公司    对指标区的老师们可以讲是小屋见大屋   更主要的是我怕麻烦 在指标区发指标需要讲解很多 表面用意
我本来书读得少 表达能力就很差  所以怕怕  但无办法做事要按照论坛规矩去办事 指标最好就是在指标区发出比较好些 各位老大 有不对的地方还请海涵啊 
直接进入主题

extdata(1)=主动特买{大于100万的主动买单}
extdata(2)=主动特卖{大于100万的主动卖单}
extdata(3)=主动大买{大于20万小于100万的主动买单}
extdata(4)=主动大卖{大于20万小于100万的主动卖单}
extdata(5)=主动中买{大于4万小于20万的主动买单}
extdata(6)=主动中卖{大于4万小于20万的主动卖单}
extdata(7)=主动小买{小于4万的主动买单}
extdata(8)=主动小卖{小于4万的主动卖单}
以上单位是 手  {100股=1手 求成交资金可以这样计算extdata(1)*100*c（价）/10000（缩小单位为万）  简单可以写成 主动特买=extdata(1)*c/100  }
extdata(9)=主力主动买入次
extdata(10)=主力主动卖出次
extdata(11) 留空
extdata(12)=ORDER(1){所有买单}
extdata(13)=ORDER(2){所有卖单}
extdata(14)=bigorder(1,1) {用法和大智慧资金函数用法一样}
extdata(15)=bigorder(2,1)
extdata(16)=bigorder(1,2)
extdata(17)=bigorder(2,2)
extdata(18)=bigorder(1,3)
extdata(19)=bigorder(2,3)

公式举例
判断句也可以用以下两种
因为有些同学喜欢使用暴力或可以免费和收费共享同一个公式所以加一判断

PD:=bigorder(1,0)=0 and bigorder(2,0)=0;{判断有没正版数据 所有成交买卖单等于0时条件成立 }

PD:=ORDER(1)=0 and ORDER(1)=0;{判断有没正版数据 所有买单卖单等于0时条件成立 }
我比较喜欢用第一句 因为大智慧有是会出现ORDER(1)假数据 用免费用户登陆时也会出现数据 不过是假的 会做成错误判断 这个现象很少出现 毕竟我碰到过几次

采用数据判断

中单买:=IF(PD,extdata(14)-extdata(16),bigorder(1,1)-bigorder(1,2));{判断有没正版数据 所有成交买卖单等于0时使用扩展数据 也即使雨杨数据 扩展数据是和雨杨数据是同步的}

以下同上
中单卖:=IF(PD,extdata(15)-extdata(17),bigorder(2,1)-bigorder(2,2));
大单买:=IF(PD,extdata(16)-extdata(18),bigorder(1,2)-bigorder(1,3));
大单卖:=IF(PD,extdata(17)-extdata(19),bigorder(2,2)-bigorder(2,3));
特大单买:=IF(PD,extdata(18),bigorder(1,3));
特大单卖:=IF(PD,extdata(19),bigorder(2,3));
小单买:=IF(PD,1-extdata(14),1-bigorder(1,1));
小单卖:=IF(PD,1-extdata(15),1-bigorder(2,1));

委买:=IF(PD,extdata(12),ORDER(1));
委卖:=IF(PD,extdata(13),ORDER(2));

主力买卖可以直接这样写

主力买:=IF(PD,extdata(16),bigorder(1,2));
主力卖:=IF(PD,extdata(17),bigorder(2,2));

下面直接解开大智慧核心公式ddE免费写法  显示数得完全和正版一样的
{DDX}
INPUT: P1(60,0,100),P2(5,0,100),P3(10,0,100);
REFLINE:0;
PD:=bigorder(1,1)=0 and bigorder(2,1)=0;
PD1:="DDEDATA@BIGORDER"(1,1)=0 and "DDEDATA@BIGORDER"(2,1)=0 ;

委买:=IF(PD,extdata(12),ORDER(1));
委卖:=IF(PD,extdata(13),ORDER(2));

ZLLR:=IF(PD,extdata(16),bigorder(1,2));
ZLLC:=IF(PD,extdata(17),bigorder(2,2));
VAR0:=MIN(COUNT(委卖,0),P1);
DDX:(ZLLR - ZLLC) * VOL/CAPITAL * 100,COLOR3D;
DDX1:EMA((ZLLR - ZLLC) * VOL/CAPITAL * 100,VAR0) * VAR0;
DDX2:MA(DDX1,P2);
DDX3:MA(DDX1,P3);
DRAWTEXTABS(0,0,'☆阿旺☆大单动向'),COLORff00ff;
1,DOTLINE;
DRAWTEXTABS(190,1,'实时数据采用:'+ ifs(PD,'雨杨','正版')),color00ffff;
DRAWTEXTABS(300,1, ifs(PD1,'雨杨数据接受失败','雨杨数据接受成功')),color00ffff;

{DDY}
INPUT: P1(60,0,100),P2(5,0,100),P3(10,0,100);
REFLINE:0;
PD:=bigorder(1,1)=0 and bigorder(2,1)=0;
PD1:="DDEDATA@BIGORDER"(1,1)=0 and "DDEDATA@BIGORDER"(2,1)=0 ;

委买:=IF(PD,extdata(12),ORDER(1));
委卖:=IF(PD,extdata(13),ORDER(2));
ZLLR:=IF(PD,extdata(16),bigorder(1,2));
ZLLC:=IF(PD,extdata(17),bigorder(2,2));

VAR0:=MIN(COUNT(委卖,0),P1);
VAR1:=EMA((2 - ZLLR - ZLLC) * VOL/(委买 + 委卖),60);
DDY:(委卖 - 委买)/CAPITAL * VAR1 * 100,COLOR3D;
DDY1:EMA((委卖 - 委买)/CAPITAL * VAR1 * 100,VAR0) * VAR0;
DDY2:MA(DDY1,P2);
DDY3:MA(DDY1,P3);
DRAWTEXTABS(0,0,'☆阿旺☆涨跌动因'),COLORff00ff;
1,DOTLINE;
DRAWTEXTABS(190,1,'实时数据采用:'+ ifs(PD,'雨杨','正版')),color00ffff;
DRAWTEXTABS(300,1, ifs(PD1,'雨杨数据接受失败','雨杨数据接受成功')),color00ffff;

{DDZ}
REFLINE:0;
PD:=bigorder(1,1)=0 and bigorder(2,1)=0;

PD1:="DDEDATA@BIGORDER"(1,1)=0 and "DDEDATA@BIGORDER"(2,1)=0 ;
委买:=IF(PD,extdata(12),ORDER(1));
委卖:=IF(PD,extdata(13),ORDER(2));
ZLLR:=IF(PD,extdata(16),bigorder(1,2));
ZLLC:=IF(PD,extdata(17),bigorder(2,2));
VAR0:=ZLLR * VOL/委买;
VAR1:=ZLLC * VOL/委卖;
VAR2:=2 * VOL/(委买 + 委卖);
DDZ:(VAR0 - VAR1)/VAR2 * 100,COLORWHITE;
FLOATRGN((VAR0 - VAR1)/VAR2 * 100,VAR0 - VAR1,VAR0 > VAR1,RGB(255,0,0),VAR0 < VAR1,RGB(0,255,0));
DRAWTEXTABS(0,0,'☆阿旺☆大单差分'),COLORff00ff;

DRAWTEXTABS(190,1,'实时数据采用:'+ ifs(PD,'雨杨','正版')),color00ffff;
DRAWTEXTABS(300,1, ifs(PD1,'雨杨数据接受失败','雨杨数据接受成功')),color00ffff;

接下来是主动买卖数据使用 其实主动买卖是对做短线比较有用 可以判断一个股票短期内有没有主力拉升  比如一个股票连跌数天或横盘数天 3日内会出现连翻红而且涨幅超过1个半点3个半点内 牛市早盘可以介入 行情普通可以收盘前买入  第二天出现小利跳出 基本上有收获

因为以上数据把他做成了扩展数据公式可以直接这样写

买:=extdata(1);{主动特买}
卖:=extdata(2);{主动特卖}
大买:=extdata(3);{主动大买}
大卖:=extdata(4);主动大卖}
主买:(买+大买)*c/100,linethick0;{求主力主动买入额  （大单+特单=主单）}
主卖:(大卖+卖)*c/100,linethick0;{求主力主动卖出额}
净额:(主买-主卖),linethick0;
三:Sum(净额,3),linethick1,colorred;
stickline(净额>0,0,净额,4,0),colorred,linethick2;
stickline(净额<0,净额,0,4,0),colorgreen,linethick2;

0,dotline,colorwhite;
十日红:count(净额>0,10),colorred;
连红:last(净额>0),colorred;

公式很简单 看法也很简单 使用却很实在 理不理解就看你自己  不是公式好看你就能赚到钱 公式是给你判别的 不是给你摆美的
版本关注地址